working on mouse lunges

/**
*   Author: Lex Talkington Design, Inc
*   August 7, 2009
*   http://www.lextalkington.com/blog
*  
*   VERSION 1.0;
*  
*   Copyright (c) 2009 Lex Talkington and Lex Talkington Design, Inc.  
*  
*   Permission is hereby granted, free of charge, to any person obtaining a copy
*   of this software and associated documentation files (the "Software"), to deal
*   in the Software without restriction, including without limitation the rights
*   to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
*   copies of the Software, and to permit persons to whom the Software is
*   furnished to do so, subject to the following conditions:
*  
*   The above copyright notice and this permission notice shall be included in
*   all copies or substantial portions of the Software.
*  
*   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
*   IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
*   FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
*   AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
*   LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
*   OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
*   THE SOFTWARE.
*
*
*   */

/**
*   EXAMPLE:
*   Assuming there is a display object on the displaylist namesd "mc"
*  
*   var xPos:Number = 55;
*   var yPos:Number = 55;
*   var visibleWidth:Number = 430;
*   var visibleHeight:Number = 430;
*   var startingViewableX:Number = (mc.width-visibleWidth)/2;  
*   var startingViewableY:Number = (mc.height-visibleHeight)/2;
*   var ease:Number = 0.7;                                     
*   var cacheIt:Boolean = true;                                
*   var _autoPan:AutoPan = new AutoPan(mc, xPos, yPos, visibleWidth, visibleHeight, startingViewableX, startingViewableY, ease, cacheIt);
*  
*   PUBLIC METHODS
*   _autoPan.slideToPoint(370,250);
*   _autoPan.slideToPoint(10,10);
*   _autoPan.stopMotion();
*   _autoPan.activateMotion();
*  
*   TO REMOVE DISPOSE
*   _autoPan.dispose();
*   _autoPan = null;
*  
*   */


package com.lextalkington.autopan {
   
    /**
     *  Class description.
     *
     *  @langversion ActionScript 3.0
     *  @playerversion Flash 9.0
     *
     *  @author Lex Talkington
     *  @since  07.08.2009
     */
   
    import flash.display.*;
    import flash.events.*;
    import flash.geom.Rectangle;

    public class AutoPan extends Sprite {
        //------------- CONSTANTS
        public static const VERSION:String = "1.0";

        //------------- PRIVATE PROPERTIES
        private var _clip:DisplayObject;
        private var _xp:Number;
        private var _yp:Number;
        private var _aw:Number;
        private var _ah:Number;
        private var _offsetx:Number;
        private var _offsety:Number;
        private var _ease:Number;
        private var _easeSlideTo:Number;
        private var _cache:Boolean;
        private var _rectangle:Rectangle;
       
        private var _clipParent:DisplayObject;
        private var _clipW:Number;
        private var _clipH:Number;
        private var _yRatio:Number;
        private var _yPos:Number;
        private var _xRatio:Number;
        private var _xPos:Number;
        private var _motionActive:Boolean;
       
        private var _toX:Number = 0;
        private var _toY:Number = 0;
       
        //----------------------------------------------------------------------------
        //-------------------------------------- CONSTRUCTOR
        //----------------------------------------------------------------------------
        /**
         *  @Constructor
         * 
         *  CURRENTLY, THIS IS SET UP ONLY TO HANDLE MOVEMENT ON A DISPLAYOBJECT THAT EXISTS ON THE DISPLAY LIST
         *  @clip reference to a DisplayObject that has been added to Display List
         *  @xp the x position of the rendered autopan
         *  @yp the y position of the rendered autopan
         *  @aw the aperture width of the autopan
         *  @ah the aperture height of the autopan
         *  @offsetx the starting postion of the image, calculated to the left of zero
         *  @offsety the starting postion of the image, calculated above zero
         *  @ease contols the amount of ease from 0-1, default is 0.7
         *  @cache toggles cacheAsBitmap, default is true
         * 
         */
        public function AutoPan(clip:DisplayObject, xp:Number, yp:Number, aw:Number, ah:Number, offsetx:Number, offsety:Number, ease:Number=0.7, cache:Boolean=true) {
            _clip = clip;
            _xp = xp;
            _yp = yp;
            _aw = aw;
            _ah = ah;
            _offsetx = offsetx;
            _offsety = offsety;
            _ease = ease;
            _easeSlideTo = ease*0.5; // we reduce the provided easing by half to use withing the moveToPoint method
            _cache = cache;
            init();
        }
       
        //----------------------------------------------------------------------------
        //-------------------------------------- PRIVATE METHODS
        //----------------------------------------------------------------------------
       
        //-----------------------------------
        //  init
        //-----------------------------------
        private function init():void {
            _clip.x = _xp;
            _clip.y = _yp;
            _clipW = _clip.width;
            _clipH = _clip.height;
            try {
                _clipParent = _clip.parent;
            } catch(e:*) {
                throw new Error("The clip ("+_clip+") you passed to AutoPan does not have a parent - it is probably not on the display list which is necessary for AutoPan to work");
                return;
            }
            // set cache
            if(_cache) _clip.cacheAsBitmap = true;
            // create rectangle for scrollrect
            _rectangle = new Rectangle(_offsetx, _offsety, _aw, _ah);
            // set scrollrect on displayObject
            _clip.scrollRect = _rectangle;
            // set mouse event to start movement
            _clip.addEventListener(MouseEvent.MOUSE_OVER, initiateMovement, false, 0, true);   
            // allow motion
            _motionActive = true;
        }
       
        //-----------------------------------
        //  initiate movement
        //-----------------------------------
        private function initiateMovement(e:Event):void {
            if(hasEventListener(Event.ENTER_FRAME)) {
                removeEventListener(Event.ENTER_FRAME, move);
                removeEventListener(Event.ENTER_FRAME, moveToPoint);
            }
            _clip.removeEventListener(MouseEvent.MOUSE_OVER, initiateMovement);
            addEventListener(Event.ENTER_FRAME, move);
        }
       
        //-----------------------------------
        //  move
        //-----------------------------------
        private function move(e:Event):void {
            var xm:int = _clipParent.mouseX;
            var ym:int = _clipParent.mouseY;

            // This catches a firefox issue where if the clip is in motion, and if you commmand-n open a new window, the ENTER_FRAME continues to fire.
            if(checkMouseLeave(xm,ym)) return;
           
            _clip.scrollRect = getXY(xm,ym);
           
            // check if the mouse is over the visible clip area
            if(!_clip.hitTestPoint(mouseX,mouseY,true)) {
                killMovement();
            }
        }
       
        //-----------------------------------
        //  check if the mouse has left the stage - added as a FireFox catch
        //-----------------------------------
        private function checkMouseLeave(xp:int,yp:int):Boolean {
            // However, it appears that all mouse x,y coords come through as negative integers when this out-of-window tracking happens. The numbers usually appear as -107374182, -107374182
            // To avoid having to add this instance to the stage and utilize the MOUSE_LEAVE event,
            // I'm killing motion if the mouse x,y are above 10,000
           
            if(xp<0) xp = -xp;
            if(yp<0) yp = -yp;
           
            if(xp>10000 || xp>10000) {
                killMovement();
                return true;
            }
            return false;
        }
       
        //-----------------------------------
        //  get X,Y : calculate x,y based on mouse position
        //-----------------------------------
        private function getXY(xp:Number,yp:Number):Rectangle {
            // calculate the X offset / positions
            _xRatio = (xp-_clip.x)/_rectangle.width;
            _xPos = _xRatio*(_clipW-_rectangle.width);

            // calculate the Y offset / positions
            _yRatio = (yp-_clip.y)/_rectangle.height;
            _yPos = _yRatio*(_clipH-_rectangle.height);

            // set the rectangles offsets
            _rectangle.x = _xPos-(_xPos-_rectangle.x)*_ease;
            _rectangle.y = _yPos-(_yPos-_rectangle.y)*_ease;

            return _rectangle;
        }
       
        //-----------------------------------
        //  kill movement
        //-----------------------------------
        private function killMovement():void {
            if(hasEventListener(Event.ENTER_FRAME)) {
                removeEventListener(Event.ENTER_FRAME, move);
                removeEventListener(Event.ENTER_FRAME, moveToPoint);
            }
            if(_motionActive) {
                if(!_clip.hasEventListener(MouseEvent.MOUSE_OVER)) {
                    _clip.addEventListener(MouseEvent.MOUSE_OVER, initiateMovement, false, 0, true);
                }
            } else {
                if(_clip.hasEventListener(MouseEvent.MOUSE_OVER)) _clip.removeEventListener(MouseEvent.MOUSE_OVER, initiateMovement);
            }
        }
       
        //-----------------------------------
        //  move to point
        //-----------------------------------
        private function moveToPoint(e:Event):void {
            _rectangle.x += (_toX-_rectangle.x)*_easeSlideTo;
            _rectangle.y += (_toY-_rectangle.y)*_easeSlideTo;
           
            var disx:Number = _toX-_rectangle.x;
            var disy:Number = _toX-_rectangle.x;
            if(disx<0) disx = -disx;
            if(disy<0) disy = -disy;
           
            if(disx<1) {
                if(disy<1) {
                    // if the clip has reached it's destination, stop motion,
                    // set the end destination to actual, exact position requested: _toX, _toY
                    killMovement();
                    _rectangle.x = _toX;
                    _rectangle.y = _toY;
                    _clip.scrollRect = _rectangle;
                    return;
                }
            }
           
            _clip.scrollRect = _rectangle;
        }
       
       
        //----------------------------------------------------------------------------
        //-------------------------------------- PUBLIC METHODS
        //----------------------------------------------------------------------------
        /**
        *   slide to point
        *   @xp Number representing a distance, in pixels, to the left of the left edge of the visible aperture
        *   @yp Number representing a distance, in pixels, above the top edge of the visible aperture
        *  
        *   */
        public function slideToPoint(xp:Number,yp:Number):void {
            _toX = xp;
            _toY = yp;
            killMovement();
            addEventListener(Event.ENTER_FRAME, moveToPoint);
        }

        //-----------------------------------
        //  stop motion
        //-----------------------------------
        public function stopMotion():void {
            _motionActive = false;
            killMovement();
        }
       
        //-----------------------------------
        //  activate motion
        //-----------------------------------
        public function activateMotion():void {
            _motionActive = true;
            killMovement();
        }
       
        //-----------------------------------
        //  dispose - removes all events, sets scrollrect to null
        //-----------------------------------
        public function dispose():void {
            _motionActive = false;
            killMovement();
            _clip.scrollRect = null;
            _clip = null;
            _rectangle = null;
            _clipParent = null;
        }
       
        //----------------------------------------------------------------------------
        //-------------------------------------- UTILITY METHODS
        //----------------------------------------------------------------------------
        private function tracer(str:*):void {
            trace("[ AutoPan ] :: ", str);
        }
       
    }
   
}